CD Fun House 8/CD Funhouse Version 8.0 - Wayzata Technology (7013) (1993).iso/pc/mac/__cd_fun/__sports/hyperfoo.00/stack.txt

Text File | 1990-10-03 | 18KB | 775 lines

-- stack: in.00
-- format: 8 (HyperCard 1)
-- flags: 0x1000 (none)
-- protect password hash: 0
-- maximum user level: 2 (typing)
-- window: Rect(x1=0, y1=0, x2=0, y2=0)
-- screen: Rect(x1=0, y1=0, x2=0, y2=0)
-- card dimensions: w=0 h=0
-- scroll: x=0 y=0
-- background count: 3
-- first background id: 2687
-- card count: 10
-- first card id: 7419
-- list block id: 8809
-- print block id: 3438
-- font table block id: 0
-- style table block id: 0
-- free block count: 0
-- free size: 0 bytes
-- total size: 107392 bytes
-- stack block size: 30208 bytes
-- created by hypercard version: 0x01208000
-- compacted by hypercard version: 0x01228000
-- modified by hypercard version: 0x01228000
-- opened by hypercard version: 0x01228000
-- patterns[0]: 0x0000000000000000
-- patterns[1]: 0x0000220000002200
-- patterns[2]: 0x8800220088002200
-- patterns[3]: 0xCC003300CC003300
-- patterns[4]: 0xCC883322CC883322
-- patterns[5]: 0xEE88BB22EE88BB22
-- patterns[6]: 0xEECCBB33EECCBB33
-- patterns[7]: 0xFFCCFF33FFCCFF33
-- patterns[8]: 0xFFEEFFBBFFEEFFBB
-- patterns[9]: 0xFFFFFFBBFFFFFFBB
-- patterns[10]: 0x8010022001084004
-- patterns[11]: 0xFFFFFFFFFFFFFFFF
-- patterns[12]: 0x8822882288228822
-- patterns[13]: 0x1122448811224488
-- patterns[14]: 0xC4800C6843023026
-- patterns[15]: 0xB130031BD8C00C8D
-- patterns[16]: 0xAA00AA00AA00AA00
-- patterns[17]: 0x8822552288225522
-- patterns[18]: 0x8855225588552255
-- patterns[19]: 0x77DD77DD77DD77DD
-- patterns[20]: 0xDB6DB6DB6DB6DB6D
-- patterns[21]: 0xAA55AA55AA55AA55
-- patterns[22]: 0x038448300C020101
-- patterns[23]: 0x8244394482010101
-- patterns[24]: 0x8814224188412214
-- patterns[25]: 0x8080413E080814E3
-- patterns[26]: 0x22048C7422179810
-- patterns[27]: 0xBE808808EB088880
-- patterns[28]: 0x25C8328964244C92
-- patterns[29]: 0xA29C41BE2AC914EB
-- patterns[30]: 0x40A00000040A0000
-- patterns[31]: 0x8040200002040800
-- patterns[32]: 0xAA00800088008000
-- patterns[33]: 0xFF80808080808080
-- patterns[34]: 0x081C22C180010204
-- patterns[35]: 0xFF808080FF080808
-- patterns[36]: 0xF87422478F172271
-- patterns[37]: 0xBF00BFBFB0B0B0B0
-- patterns[38]: 0xFF7FBE5DA2418000
-- patterns[39]: 0xFAF5FAF5A050A050
-- checksum: 0x0
----- HyperTalk script -----
on Runplay
  global kick, players, post, qtr, ty

  go to card 5
  XFootball (ty*3)+106,(ty*3)+106
  if players=1 then
    hide button 2
  else
    hide button 3
    show button 6
  end if

  hide card field 1
  hide card field 2
  Update
  if post=1 then
    visual effect iris open
    go to card "Goal Post"
  end if
  if kick=1 then
    wait for 1 second
    visual effect scroll down
    go to card "KICK OFF"
  end if
  if qtr=6 then
    visual effect dissolve slow
    go to card "Game Over"
  end if

end Runplay

on Setup
  global ty,td,sf,pen,dwn,time,ptime,qtr,yop,kick,dir,ofns,team1,mdw
  global score1,score2,play,ds,name1,name2,t1p,t1r,t2p,t2r,lastdef
  global defcnt

  put 250 into ds
  put "KICK OFF!" into play
  put 0 into ofns
  if dir=0 then put 65 into ty
  else put 35 into ty

  put 0 into lastdef
  put 0 into defcnt
  put 0 into t1p
  put 0 into t1r
  put 0 into t2p
  put 0 into t2r
  put 0 into dwn
  put 0 into mdw
  put 900 into time
  put 0 into ptime
  put 1 into qtr
  put 1 into yop
  put 1 into kick
  visual effect dissolve slow
  go to card 5
  put score1 into card field 6
  put score2 into card field 7
  put name1 into card field 8
  put name2 into card field 9
  put qtr into card field 14
  set dragSpeed to ds
  Runplay
end Setup

on Drawball
  global ty

  XFootball (ty*3)+106,(ty*3)+106
end Drawball

on Cointoss
  global coin, players, coinres, team1, startt

  show card button 2
  show card button 3
  put the random of 10 into toss
  if toss<=5 and coin is true or toss>5 and coin is false then
    put true into coinres
    show card field 3
  end if

  if toss<=5 and coin is false or toss>5 and coin is true then
    put false into coinres
    show card field 4
    if players=1 then
      click at the location of card button 2
      click at the location of card button 5
      put true into team1
      put true into startt
      put 0 into dir
    end if
  end if
end Cointoss

on Teamnames
  global players, name1, name2, coinres, comp

  wait for 1 second
  if players=1 then
    if coinres is true then
      ask "What is your team's name?"
      put it into name1
      put "Macintosh" into name2
      put false into comp
    else
      ask "What is your team's name?"
      put it into name2
      put "Macintosh" into name1
      put true into comp
    end if
  else
    ask "Please name the team who won the toss:"
    put it into name1
    ask "Please name the team who lost the toss:"
    put it into name2
  end if
  wait for 1 second
  Setup
end Teamnames


on Penalties
  global ty, dwn, dir, yop, pen, drop, inc

  put 0 into pen
  put the random of 100 into p
  if p>=95 then
    play "Refs Whistle"
    put 0 into drop
    put 0 into inc
    put 0 into yop
    put 1 into pen
    put the random of 100 into q
    if q>=50 and q<=100 then put 5 into yop
    if q>=28 and q<50 then put 10 into yop
    if q>=0 and q<28 then put 15 into yop
    put the random of 100 into q
    if q>50 then put (-yop) into yop
    if q>75 then go to card "Ditka"
    if yop=-5 and q>75 then play "Falsestart"
    if (yop=10 or yop=-10) then play "Holding"
    if yop=15 and q<25 then play "Roughing the Passer"
    if dir=0 then
      if ty<=15 and yop<0 then put trunc(-ty/2) into yop
      if ty>=85 and yop>0 then put trunc((100-ty)/2) into yop
    end if
    if dir=1 then
      if ty<=15 and yop>0 then put trunc(ty/2) into yop
      if ty>=85 and yop<0 then put trunc(-(100-ty)/2) into yop
    end if
    put dwn-1 into dwn
  end if
end Penalties


on Down
  global dwn, dir, ty, fdown, team1,mdw

  if dwn=0 then
    if dir=0 then
      show card button 7
      hide card button 8
    else
      show card button 8
      hide card button 7
    end if
  end if

  if dir=0 then
    if ty>=fdown then
      put 0 into dwn
      put 0 into mdw
      if ty>=90 then put 100 into fdown
      else put ty+10 into fdown
    end if
  else
    if ty<=fdown then
      put 0 into dwn
      put 0 into mdw
      if ty<=10 then put 0 into fdown
      else put ty-10 into fdown
    end if
  end if
  put dwn+1 into dwn
  put mdw+1 into mdw
  if dwn=5 then
    put 1 into dwn
    put 1 into mdw
    if team1 is true then
      put false into team1
    else
      put true into team1
    end if
    if dir=0 then
      put ty-10 into fdown
      put 1 into dir
    else
      put ty+10 into fdown
      put 0 into dir
    end if
    if dir=0 then
      show card button 7
      hide card button 8
    else
      show card button 8
      hide card button 7
    end if
  end if
end Down

on Yardline
  global ty, ydl, td, sf, dir

  put false into td
  put false into sf
  if ty>=100 and dir=0 then Touchdown
  if ty<=0 and dir=1 then Touchdown
  if ty>=100 and dir=1 then Safty
  if ty<=0 and dir=0 then Safty
  put ty into ydl
  if ty>50 then put 100-ty into ydl
end Yardline

on Placemarker
  global ty, dir, dwn, dm,mdw, kick

  if mdw=1 and kick=0 then
    if dir=0 then put (3*ty)+121 into dm
    else put (3*ty)+92 into dm
    set loc of button 10 to dm,97
  end if
end Placemarker

on Timer
  global qtr, ptime, time, ty, dir,fdown,min,sec,kick,team1,startt,dm
  global sec1, sec2, min1, min2, score1, score2

  put time-ptime into time
  put trunc(time/60) into min
  put (time/60-(min))*60 into sec
  if time<0 then
    play "Refs Whistle"
    put "End of quarter" into card field 21
    wait 1 second
    put qtr+1 into qtr
    if qtr=5 then
      if score1=score2 then
        put 5 into qtr
      else
        put 6 into qtr
      end if
    end if
    XFootball (3*ty)+106,(3*(100-ty))+106
    put 100-ty into ty
    put 100-fdown into fdown
    if dir=0 then put 1 into dir
    else put 0 into dir
    put 512-dm into dm
    put dm into markH
    set loc of button 10 to markH,97
    if qtr=3 or qtr=5 then
      if startt is true then put false into team1
      else put true into team1
      put 1 into kick
      if dir=0 then put 65 into ty
      else put 35 into ty
    end if
    put 900 into time
    put trunc(time/60) into min
    put (time/60-(min))*60 into sec
    if qtr=2 or qtr=4 then Drawball
    if qtr=5 then put "S" into card field 14
    else put qtr into card field 14
    if dir=0 then
      show card button 7
      hide card button 8
    else
      show card button 8
      hide card button 7
    end if
  end if
  put trunc((.01)+sec/10) into sec1
  put sec-(10*sec1) into sec2
  put trunc(min/10) into min1
  put min-(10*min1) into min2
end Timer

on Update
  global ty, fdown, dwn, dir, ydl, score1, score2, name1, name2, team1
  global td, qtr, min, sec, players, comp, def, yop, ofns, kick, pen
  global sec1,sec2,min1,min2, play, post, ds, drop, inc, plytyp
  global p

  put play into card field 21
  if pen>0 then
    show card field 10
    show card field 11
    put yop into card field 11
    wait for 1 second
    hide card field 10
    hide card field 11
  end if
  if pen=0 then Turnovers
  if (kick=0) then
    if dir=0 then
      put ty+yop into fty
      put -drop into drop
      put -inc into inc
    else
      put ty-yop into fty
    end if
    if fty<0 then put -5 into fty
    if fty>100 then put 105 into fty
    put (ty*3)+106 into s
    put (fty*3)+106 into f
    XFootball s,s+drop
    if drop<>0 then wait 20 ticks
    if inc<>0 then
      XFootball s+drop,s-inc
      put "Incomplete" into card field 21
      wait 30 ticks
      XFootball s-inc,s
    else
      XFootball s+drop,f
      if p<7 and plytyp=1 and pen=0 then
        put "Interference" into card field 21
        play "PassInterference"
      end if
    end if
    put fty into ty
  end if
  Yardline
  Down
  Placemarker
  Timer
  if ofns>97 then
    if ofns=98 then put "TOUCHDOWN!!" into card field 21
    if ofns=99 then put "SAFETY!!" into card field 21
    wait 1 second
  end if
  put dwn into card field 3
  put ydl into card field 5
  if kick=0 then
    put score1 into card field 6
    put score2 into card field 7
  end if
  if team1 is true then
    show card button 4
    hide card button 5
  else
    show card button 5
    hide card button 4
  end if
  put min1 & min2 && ":" && sec1 & sec2 into card field 13
  if players=1 and comp is true then
    if team1 is true then
      show button 6
      hide button 3
    else
      show button 3
      hide button 6
    end if
  end if
  if players=1 and comp is false then
    if team1 is false then
      show button 6
      hide button 3
    else
      show button 3
      hide button 6
    end if
  end if
  put abs(ty-fdown) into card field 4
  if fdown=100 or fdown=0 then put "G" into card field 4
  put the random of 100 into mad
  -- play "Madden-79"--
  if mad<10 then
    if plytyp=0 then
      if mad<2 or mad>97 then play "Madden-79"
      if mad>=2 and mad<4 then play "Madden-Bighole"
      if mad>=4 and mad<5 then play "Madden-Block"
      if mad>=5 and mad<7 then play "Madden-Boom"
      if mad>=7 and mad<9 then play "Madden-Fbshould"
      if mad>=9 and mad<10 then play "Madden1-5"
    end if
    if plytyp=1 then
      if mad<2 or mad>97 then play "Madden-Ask"
      if mad>=2 and mad<4 then play "Madden-Lookin"
      if mad>=4 and mad<6 then play "Madden-Passprotect"
      if mad>=6 and mad<8 then play "Madden-Pretty Good"
      if mad>=8 and mad<10 then play "Madden-Tough"
    end if
  end if
end Update

on Touchdown
  global team1, score1, score2, ty, dir, td, kick, good, post,ofns
  global intrcpt, qtr, play

  put the random of 4 into sndtd
  if sndtd=1 then play "Touchdown"
  if sndtd=2 then play "Touchdown2"
  if sndtd=3 then play "Touchdown3"
  if sndtd=4 then play "Touchdown4"
  put "Touchdown" into play
  put 98 into ofns
  if qtr=5 then put 6 into qtr
  put true into td
  put 1 into kick
  if dir=0 then
    put 1 into dir
    put 35 into ty
  else
    put 0 into dir
    put 65 into ty
  end if
  if team1 is true then
    put score1+6 into score1
  else
    put score2+6 into score2
  end if
  put the random of 99 into expnt
  if expnt>=95 then
    put 0 into epv
    put false into good
    put 1 into post
  else
    put 1 into epv
    put true into good
    put 1 into post
  end if
  if team1 is true then
    put score1+epv into score1
  else
    put score2+epv into score2
  end if

  if team1 is true then
    put false into team1
  else
    put true into team1
  end if

  wait for 1 second

end Touchdown

on Safty
  global team1, score1, score2, ty, dir, td, kick, ofns, qtr, play

  put "Safty" into play
  put 99 into ofns
  if qtr=5 then put 6 into qtr
  play "Refs Whistle"
  if team1 is true then
    put score2+2 into score2
  else
    put score1+2 into score1
  end if

  if team1 is true then
    put false into team1
  else
    put true into team1
  end if

  if dir=0 then
    put 1 into dir
    put 20 into ty
  else
    put 0 into dir
    put 80 into ty
  end if
  put true into td
  put 1 into kick
end Safty

on Turnovers
  global plytyp, good, kick, onside, intrcpt

  put 0 into intrcpt
  if good is true or kick=1 then exit Turnovers
  put the random of 100 into t
  if onside=1 then put 40 into max
  else put 4 into max
  if t<=max and plytyp=0 then Fumble
  if t<=5 and plytyp=1 then Interception
  put 0 into onside
end Turnovers

on Fumble
  global team1, ty, dir, td, dwn, yop
  play "Fumble"
  show card field 12
  put the random of 20 into exyd
  if exyd>=10 then put 4 into dwn
  wait for 2 seconds
  hide card field 12
end Fumble



on FieldGoal

  global ty, dwn, dir, team1, score1, score2, good, yop, kick, ofns,post
  global qtr, play, drop, inc

  put "Field Goal" into play
  put 0 into drop
  put 0 into inc
  put 4 into ofns
  put 0 into yop
  if dir=0 then put 110-ty into dis
  else put ty+10 into dis
  put the random of 75 into prb
  if prb>=dis and prb<=75 then
    if qtr=5 then put 6 into qtr
    put true into good
    if team1 is true then
      put score1+3 into score1
      put false into team1
    else
      put score2+3 into score2
      put true into team1
    end if

    if dir=0 then
      put 35 into ty
      put 1 into dir
    else
      put 65 into ty
      put 0 into dir
    end if
  end if

  if good is true then
    put 1 into kick
  end if
  put 4 into dwn
  put 1 into post

end FieldGoal


on Interception

  global ty, dwn, dir, fdown, team1, ptime, fdown, yop, ofns, plytyp,mdw
  global play, ds, drop, inc, intrcpt

  put "Interception" into play
  put 0 into inc
  put 0 into drop
  put 0 into plytyp
  put 1 into ofns
  put 14 into ptime
  put the random of 99 into kick
  put the random of 99 into rtn
  if kick >= 95 and kick <100 then put 55 into ko
  if kick >= 90 and kick <95 then put 48 into ko
  if kick >= 70 and kick <90 then put 34 into ko
  if kick >= 40 and kick <70 then put 25 into ko
  if kick <40 then put 16 into ko

  if rtn >= 97 and rtn <100 then put 100 into r
  if rtn >= 94 and rtn <97 then put 65 into r
  if rtn >= 89 and rtn <94 then put 47 into r
  if rtn >= 75 and rtn <89 then put 33 into r
  if rtn >= 65 and rtn <75 then put 25 into r
  if rtn >= 30 and rtn <65 then put 16 into r
  if rtn >= 15 and rtn <30 then put 9 into r
  if rtn <15 then put 5 into r
  go to card 5
  set dragSpeed to ds
  if dir=0 then
    put ty+ko into fty
    put -15 into dr
  else
    put ty-ko into fty
    put 15 into dr
  end if
  if fty>100 then put 102 into fty
  if fty<0 then put -2 into fty
  XFootball (ty*3)+106,(ty*3)+106+dr
  wait 20 ticks
  XFootball (ty*3)+106+dr,(fty*3)+106
  put fty into ty

  show card field 22
  put 0 into dwn
  put 0 into mdw
  put r into yop
  if dir=1 then
    put ty+yop+10 into fdown
  else
    put ty-yop-10 into fdown
  end if
  if dir=0 then put 1 into dir
  else put 0 into dir
  if team1 is true then put false into team1
  else put true into team1
  wait 1 second
  hide card field 22
  if (dir=0 and ty+yop>=100) then put 1 into intrcpt
  if (dir=1 and ty-yop<=0) then put 1 into intrcpt

end Interception

on Punt
  global ty, dwn, dir, fdown, team1, ptime, fdown, yop, ofns, plytyp,mdw
  global play, ds, drop, inc

  put "Punt" into play
  put 0 into inc
  put 0 into drop
  put 0 into plytyp
  put 1 into ofns
  put 14 into ptime
  put the random of 99 into kick
  put the random of 99 into rtn
  if kick >= 95 and kick <100 then put 65 into ko
  if kick >= 90 and kick <95 then put 58 into ko
  if kick >= 70 and kick <90 then put 44 into ko
  if kick >= 40 and kick <70 then put 50 into ko
  if kick <40 then put 47 into ko
  if rtn >= 97 and rtn <100 then put 100 into r
  if rtn >= 94 and rtn <97 then put 30 into r
  if rtn >= 89 and rtn <94 then put 25 into r
  if rtn >= 75 and rtn <89 then put 7 into r
  if rtn >= 65 and rtn <75 then put 15 into r
  if rtn >= 30 and rtn <65 then put 0 into r
  if rtn >= 15 and rtn <30 then put 5 into r
  if rtn <15 then put 8 into r
  go to card 5
  if dir=0 then
    put ty+ko into fty
  else
    put ty-ko into fty
  end if
  XFootball (ty*3)+106,(fty*3)+106
  put fty into ty
  put 0 into dwn
  put 0 into mdw
  put r into yop
  if dir=1 then
    if ty+yop<=0 then
      put 19 into ty
      put 1 into yop
      XFootball 19,20
    end if
    put ty+yop+10 into fdown
  else
    if ty-yop>=100 then
      put 81 into ty
      put 1 into yop
      XFootball 81,80
    end if
    put ty-yop-10 into fdown
  end if
  if dir=0 then put 1 into dir
  else put 0 into dir
  if team1 is true then put false into team1
  else put true into team1
  Runplay
end Punt

on Runup
  global team1, pen, yop, t1r, t2r
  Penalties
  if team1 is true then
    if pen=0 then
      put yop+t1r into t1r
    end if
  else
    if pen=0 then
      put yop+t2r into t2r
    end if
  end if
end Runup

on Passup
  global team1, pen, yop, t1p, t2p, inc, p, ty
  Penalties
  put the random of 100 into p
  if p<7 and pen=0 then
    put inc into yop
    put 0 into inc
    if yop<10 then put 22 into yop
    if yop+ty>99 or ty-yop<1 then
      put 100 into p
      put yop into inc
      put 0 into yop
    end if
  end if
  if team1 is true then
    if pen=0 then
      put yop+t1p into t1p
    end if
  else
    if pen=0 then
      put yop+t2p into t2p
    end if
  end if
end Passup